Step 1 形态模型
TITLE: Multiple indicator RI-CLPM, 5 waves, with 3 indicators for
each variable at each wave (30 observed variables) and with
random intercepts for each indicator separately.
DATA: FILE = RICLPM-MI.dat;
VARIABLE: NAMES = x11 x12 x13 x21 x22 x23 x31 x32 x33
x41 x42 x43 x51 x52 x53 y11 y12 y13
y21 y22 y23 y31 y32 y33 y41 y42 y43
y51 y52 y53;
ANALYSIS: MODEL = NOCOV;
MODEL:
!构建每个时间点相同指标的随机截距
RIX1 BY x11@1 x21@1 x31@1 x41@1 x51@1;
RIX2 BY x12@1 x22@1 x32@1 x42@1 x52@1;
RIX3 BY x13@1 x23@1 x33@1 x43@1 x53@1;
RIY1 BY y11@1 y21@1 y31@1 y41@1 y51@1;
RIY2 BY y12@1 y22@1 y32@1 y42@1 y52@1;
RIY3 BY y13@1 y23@1 y33@1 y43@1 y53@1;
RIX1-RIY3 WITH RIX1-RIY3;
!构建潜在变量
WFX1 BY x11-x13;
WFX2 BY x21-x23;
WFX3 BY x31-x33;
WFX4 BY x41-x43;
WFX5 BY x51-x53;
WFY1 BY y11-y13;
WFY2 BY y21-y23;
WFY3 BY y31-y33;
WFY4 BY y41-y43;
WFY5 BY y51-y53;
!个体内自回归和交叉滞后路径
WFX2 WFY2 ON WFX1 WFY1;
WFX3 WFY3 ON WFX2 WFY2;
WFX4 WFY4 ON WFX3 WFY3;
WFX5 WFY5 ON WFX4 WFY4;
!同一时间变量间相关
WFX1 WITH WFY1;
WFX2 WITH WFY2;
WFX3 WITH WFY3;
WFX4 WITH WFY4;
WFX5 WITH WFY5;
OUTPUT: TECH1 STDYX SAMPSTAT CINTERVAL;
Step 2 弱测量不变性
TITLE: Multiple indicator RI-CLPM, 5 waves, with 3 indicators for
each variable at each wave (30 observed variables) and with
random intercepts for each indicator separately. Fitting a model
with constraints to ensure weak factorial invariance.
DATA: FILE = RICLPM-MI.dat;
VARIABLE: NAMES = x11 x12 x13 x21 x22 x23 x31 x32 x33
x41 x42 x43 x51 x52 x53 y11 y12 y13
y21 y22 y23 y31 y32 y33 y41 y42 y43
y51 y52 y53;
ANALYSIS: MODEL = NOCOV; ! Sets all default covariances to zero
MODEL:
RIX1 BY x11@1 x21@1 x31@1 x41@1 x51@1;
RIX2 BY x12@1 x22@1 x32@1 x42@1 x52@1;
RIX3 BY x13@1 x23@1 x33@1 x43@1 x53@1;
RIY1 BY y11@1 y21@1 y31@1 y41@1 y51@1;
RIY2 BY y12@1 y22@1 y32@1 y42@1 y52@1;
RIY3 BY y13@1 y23@1 y33@1 y43@1 y53@1;
RIX1-RIY3 WITH RIX1-RIY3;
!加粗为在第一步基础上修改的代码，通过在语句的括号中填加相同的标签，限定潜变量的载荷相等
WFX1 BY x11-x13 (a b c);
WFX2 BY x21-x23 (a b c);
WFX3 BY x31-x33 (a b c);
WFX4 BY x41-x43 (a b c);
WFX5 BY x51-x53 (a b c);
WFY1 BY y11-y13 (d e f);
WFY2 BY y21-y23 (d e f);
WFY3 BY y31-y33 (d e f);
WFY4 BY y41-y43 (d e f);
WFY5 BY y51-y53 (d e f);
WFX2 WFY2 ON WFX1 WFY1;
WFX3 WFY3 ON WFX2 WFY2;
WFX4 WFY4 ON WFX3 WFY3;
WFX5 WFY5 ON WFX4 WFY4;
WFX1 WITH WFY1;
WFX2 WITH WFY2;
WFX3 WITH WFY3;
WFX4 WITH WFY4;
WFX5 WITH WFY5;
OUTPUT: TECH1 STDYX SAMPSTAT CINTERVAL;
Step 3 强测量不变性
TITLE: Multiple indicator RI-CLPM, 5 waves, with 3 indicators for
each variable at each wave (30 observed variables) and with
random intercepts for each indicator separately. Fitting a model
with constraints to ensure strong factorial invariance.
DATA: FILE = RICLPM-MI.dat;
VARIABLE: NAMES = x11 x12 x13 x21 x22 x23 x31 x32 x33
x41 x42 x43 x51 x52 x53 y11 y12 y13
y21 y22 y23 y31 y32 y33 y41 y42 y43
y51 y52 y53;
ANALYSIS: MODEL = NOCOV; ! Sets all default covariances to zero
MODEL:
RIX1 BY x11@1 x21@1 x31@1 x41@1 x51@1;
RIX2 BY x12@1 x22@1 x32@1 x42@1 x52@1;
RIX3 BY x13@1 x23@1 x33@1 x43@1 x53@1;
RIY1 BY y11@1 y21@1 y31@1 y41@1 y51@1;
RIY2 BY y12@1 y22@1 y32@1 y42@1 y52@1;
RIY3 BY y13@1 y23@1 y33@1 y43@1 y53@1;
RIX1-RIY3 WITH RIX1-RIY3;
WFX1 BY x11-x13 (a b c);
WFX2 BY x21-x23 (a b c);
WFX3 BY x31-x33 (a b c);
WFX4 BY x41-x43 (a b c);
WFX5 BY x51-x53 (a b c);
WFY1 BY y11-y13 (d e f);
WFY2 BY y21-y23 (d e f);
WFY3 BY y31-y33 (d e f);
WFY4 BY y41-y43 (d e f);
WFY5 BY y51-y53 (d e f);
!加粗为在第二步基础上修改的代码，方括号为估计截距，通过在语句的括号中填加相同的标签，限定潜变量的载荷相等，同时使用星号，自由估计潜变量的截距。
[x11 x12 x13] (g h i);
[x21 x22 x23] (g h i);
[x31 x32 x33] (g h i);
[x41 x42 x43] (g h i);
[x51 x52 x53] (g h i);
[y11 y12 y13] (j k l);
[y21 y22 y23] (j k l);
[y31 y32 y33] (j k l);
[y41 y42 y43] (j k l);
[y51 y52 y53] (j k l);
[WFX2* WFX3* WFX4* WFX5*];
[WFY2* WFY3* WFY4* WFY5*];
WFX2 WFY2 ON WFX1 WFY1;
WFX3 WFY3 ON WFX2 WFY2;
WFX4 WFY4 ON WFX3 WFY3;
WFX5 WFY5 ON WFX4 WFY4;
WFX1 WITH WFY1;
WFX2 WITH WFY2;
WFX3 WITH WFY3;
WFX4 WITH WFY4;
WFX5 WITH WFY5;
OUTPUT: TECH1 STDYX SAMPSTAT CINTERVAL;
Step 4 在潜变量层面应用RI-CLPM（最终模型）
TITLE: Multiple indicator RI-CLPM, 5 waves with 3 indicators for each
variable at each wave (30 observed variables). Fitting a model
with constraints to ensure strong factorial invariance, with
the RI-CLPM at the latent level.
DATA: FILE = RICLPM-MI.dat;
VARIABLE: NAMES = x11 x12 x13 x21 x22 x23 x31 x32 x33
x41 x42 x43 x51 x52 x53 y11 y12 y13
y21 y22 y23 y31 y32 y33 y41 y42 y43
y51 y52 y53;
ANALYSIS: MODEL = NOCOV; ! Sets all default covariances to zero
MODEL:
FX1 BY x11-x13 (a b c);
FX2 BY x21-x23 (a b c);
FX3 BY x31-x33 (a b c);
FX4 BY x41-x43 (a b c);
FX5 BY x51-x53 (a b c);
FY1 BY y11-y13 (d e f);
FY2 BY y21-y23 (d e f);
FY3 BY y31-y33 (d e f);
FY4 BY y41-y43 (d e f);
FY5 BY y51-y53 (d e f);
[x11 x12 x13] (g h i);
[x21 x22 x23] (g h i);
[x31 x32 x33] (g h i);
[x41 x42 x43] (g h i);
[x51 x52 x53] (g h i);
[y11 y12 y13] (j k l);
[y21 y22 y23] (j k l);
[y31 y32 y33] (j k l);
[y41 y42 y43] (j k l);
[y51 y52 y53] (j k l);
[FX2* FX3* FX4* FX5*];
[FY2* FY3* FY4* FY5*];
RIX BY FX1@1 FX2@1 FX3@1 FX4@1 FX5@1;
RIY BY FY1@1 FY2@1 FY3@1 FY4@1 FY5@1;
RIX WITH RIY;
FX1-FY5@0;
WFX1 BY FX1@1;
WFX2 BY FX2@1;
WFX3 BY FX3@1;
WFX4 BY FX4@1;
WFX5 BY FX5@1;
WFY1 BY FY1@1;
WFY2 BY FY2@1;
WFY3 BY FY3@1;
WFY4 BY FY4@1;
WFY5 BY FY5@1;
WFX2 WFY2 ON WFX1 WFY1;
WFX3 WFY3 ON WFX2 WFY2;
WFX4 WFY4 ON WFX3 WFY3;
WFX5 WFY5 ON WFX4 WFY4;
WFX1 WITH WFY1;
WFX2 WITH WFY2;
WFX3 WITH WFY3;
WFX4 WITH WFY4;
WFX5 WITH WFY5;
OUTPUT: TECH1 STDYX SAMPSTAT CINTERVAL;
