从今天开始，我们搬运Scott Cunningham的“Pedro’s diff in diff checklist”【有兴趣的人可以点击这里关注他的blog】。

大家也许还记得，Sant' Anna有一个十步DID：

第一步：画出处理模式图

今天的第二步利用Aneja, Donohue and Zhang (2011，AER)的数据。美国FBI从1930年开始实施UCR项目，旨在建立可信的犯罪统计数据。UCR包括来自18000家执法部门的数据，这些机构都是自愿参与，因此，并不会完全合作。例如，有一些机构每个月上报完整的数据，有的机构一年才上报一次，有的数据有缺失，有的甚至一点数据没有。尽管如此，UCR项目仍然是美国犯罪记录最全的数据库，记录了关键的犯罪和政策干预等等信息。

作者用1970-2007年的51个地区数据。

step 0：创建初次处理日期变量

我们要创建初次处理日期变量。主要并不是处理变量。也就是说，政策实施初次实施年份设定为1，否则为0。这个变量在很多交叠DID估计量中被称为cohort变量，例如CSDID。需要注意的是，如果个体从未处理，那么，我们也需要用0来指代缺失处理日期。

clear all
capture log close


use "/Users/xuwenli/Library/CloudStorage/OneDrive-个人/DSGE建模及软件编程/教学大纲与讲稿/应用计量经济学讲稿/应用计量经济学讲稿与code/data/mixtape/concealed_carry_state.dta", clear

* Load packages needed for panelView
* net install grc1leg, from(http://www.stata.com/users/vwiggins) replace
* net install gr0075, from(http://www.stata-journal.com/software/sj18-4) replace
* ssc install labutil, replace
* ssc install sencode, replace
* cap ado uninstall panelview //in-case already installed
* net install panelview, all replace from("https://yiqingxu.org/packages/panelview_stata")

* Generate a treatment date variable
gen     treat_date = 2020 	// never treated
replace treat_date = 1970 if shalll==1 & aftr==0 // always treated
replace treat_date = 1994 if fipsstat==2 		 // treatment cohorts
replace treat_date = 1994 if fipsstat==4
replace treat_date = 1995 if fipsstat==5
replace treat_date = 2003 if fipsstat==8
replace treat_date = 1987 if fipsstat==12
replace treat_date = 1989 if fipsstat==13
replace treat_date = 1990 if fipsstat==16
replace treat_date = 1980 if fipsstat==18
replace treat_date = 2006 if fipsstat==20
replace treat_date = 1996 if fipsstat==21
replace treat_date = 1996 if fipsstat==22
replace treat_date = 1985 if fipsstat==23
replace treat_date = 2001 if fipsstat==26
replace treat_date = 2003 if fipsstat==27
replace treat_date = 1990 if fipsstat==28
replace treat_date = 2003 if fipsstat==29
replace treat_date = 1991 if fipsstat==30
replace treat_date = 2006 if fipsstat==31
replace treat_date = 1995 if fipsstat==32
replace treat_date = 2003 if fipsstat==35
replace treat_date = 1995 if fipsstat==37
replace treat_date = 2004 if fipsstat==39
replace treat_date = 1995 if fipsstat==40
replace treat_date = 1990 if fipsstat==41
replace treat_date = 1989 if fipsstat==42
replace treat_date = 1996 if fipsstat==45
replace treat_date = 1994 if fipsstat==47
replace treat_date = 1995 if fipsstat==48
replace treat_date = 1995 if fipsstat==49
replace treat_date = 1988 if fipsstat==51
replace treat_date = 1989 if fipsstat==54
replace treat_date = 1994 if fipsstat==56

// Define the labels for each unique value
label define treat_date_lbl 2020 "never treated" ///
                      1970 "always treated" ///
                      1980 "1980 cohort" ///
                      1985 "1985 cohort" ///
                      1987 "1987 cohort" ///
                      1988 "1988 cohort" ///
                      1989 "1989 cohort" ///
                      1990 "1990 cohort" ///
                      1991 "1991 cohort" ///
                      1994 "1994 cohort" ///
                      1995 "1995 cohort" ///
                      1996 "1996 cohort" ///
                      2001 "2001 cohort" ///
                      2003 "2003 cohort" ///
                      2004 "2004 cohort" ///
                      2006 "2006 cohort"

// Assign the labels to the treat_date variable
label values treat_date treat_date_lbl

drop if state==""
encode state, gen(id)

gen treat = 0
replace treat=1 if year>=treat_date

第一步：画出处理模式图：

* Visualizing rollouts to count the number of units in a cohort.
panelview lmur treat, prepost bytiming i(state) t(year) type(treat) xtitle("Year") ytitle("State") title("Treatment Status by Timing Group") legend(label(1 "Never treated") label(2 "Treated (Pre)") label(3 "Treated (Post)"))

第二步：每类的处理个体数量

这一步就是数数，数出每一类（初次处理类别）中有多少处理个体。我们可以用表格的形式呈现这些结果。

// Tabulate treat_date for the year 1970
tabulate treat_date if year == 1970, matcell(freq) matrow(names)

也许我们也想展示每类处理中包含哪些个体，也就是个体的名字：

* Get state names by treat_date for the year 1970
levelsof treat_date, local(treat_dates)

foreach x in `treat_dates' {
    display "Treatment date: `x'"
    tabulate state if treat_date == `x'
}

* Copy output and give it to ChatGPT-4o to make a pretty table for us in LaTeX as I'm too lazy to do it here. 

上面输出的结果很多，所以Cunningham建议用GPT来直接输出Latex命令。