倍分法：DID是否需要随机分组？

👇 连享会 · 推文导航 | www.lianxh.cn

• 🍎 Stata：Stata基础 | Stata绘图 | Stata程序 | Stata新命令
• 📘 论文：数据处理 | 结果输出 | 论文写作 | 数据分享
• 💹 计量：回归分析 | 交乘项-调节  | IV-GMM | 时间序列 | 面板数据  | 空间计量 | Probit-Logit | 分位数回归
• ⛳ 专题：SFA-DEA | 生存分析  | 爬虫 | 机器学习 | 文本分析
• 🔃 因果：DID | RDD | 因果推断 | 合成控制法 | PSM-Matching
• 🔨 工具：工具软件 | Markdown | Python-R-Stata
• 🎧 课程：最新专题 |  计量专题 | 关于连享会

🍓 课程推荐：2024 空间计量专题
主讲老师：范巧 (兰州大学)
课程时间：2024 年 10 月 2-4 日 (三天)
课程咨询：王老师 18903405450（微信）

 课程特色 · 2024空间计量：

👉  一、从“零基础”到“高水平”的课程设计

• 兼顾基础知识、主流模型与前沿模型
• 既考虑软件安装、程序编写以及空间权重矩阵设计等 基础知识 讲授，更强调时空面板地理加权回归模型、贝叶斯空间计量模型、矩阵指数模型、空间计量交互模型与空间面板似不相关回归模型等 前沿模型 的传授。

👉  二、“保姆级”的空间计量代码

• 编写与校准所有模型的MATLAB代码，简化实操环节
• 模型的估计与检验等 仅按照提供的Excel数据版式 搜集与整理原始数据，即可一次性出结果并作图。

👉   三、“最多上新” 的内容体系

• 新增 矩阵指数模型、短面板空间似不相关模型、空间计量交互模型、贝叶斯空间计量模型等
• 新增 前沿应用案例，包括空间计量与索洛余值法、随机前沿分析与数据包络分析等的互嵌研究，阐释基于空间计量的产业空间结构优化评价方法。
• 新增 Dagum空间基尼系数、核密度估计、空间马尔科夫链与空间收敛性等内容，阐释现实研究中对空间收敛性的应用“谬误”。 

作者：胡艺泽 (广东金融学院)
邮箱：huyize@gduf.edu.cn

编者按：本文主要是对下文结果进行重现，特此致谢！

Source: Cook C J, Shah M. Aggregate Effects from Public Works: Evidence from India[J]. Review of Economics and Statistics, 2020: 1-38. -PDF- -Replication Files- 

目录

• 0. 写在前面

• 1. 研究问题

• 2. 实证模型及主回归结果

• 3. 共同趋势假设检验

• 4. 异质性分析

• 5. 稳健性检验

• 6. 将灯光变为收入

• 7. 总结

• 8. 参考文献

• 9. 相关推文

温馨提示： 文中链接在微信中无法生效。请点击底部「阅读原文」。或直接长按/扫描如下二维码，直达原文：

0. 写在前面

DID 是否需要随机分组？答案是不需要。如果满足随机分组，那么直接对比实验组和对照组的结果就能得出因果关系。而 DID 的使用需要满足共同趋势假设，以建立基于反事实的因果推断。

本文以 RES 2020 的一篇研究为例，并根据作者「个人主页」提供的代码对该论文的主要结果进行重现。在此过程中，本文主要使用的 Stata 命令包括：reghdfe、coefplot、bacondecomp，需提前安装。

1. 研究问题

发展中国家一直存在着如何向低收入群体转移资金的讨论。目前主要方式包括：公共工程项目、有条件现金转让、无条件现金转让。其中，公共工程项目相对现金转让的好处主要体现在两个方面：

• 第一，公共工程项目提供的是工作而不是钱，不太贫困的人不会去申请做这些工作，因此更可能帮助真正需要帮助的人；
• 第二，公共工程项目可以防止受益者产生依赖，因为一旦人们找到更好的工作，便会从项目中退出。

印度农村就业保障计划 (NREGS) 是世界上最大的公共工程项目，具体来看：

• 有 6 亿农村居民有资格参与该项目；
• 财政拨款占印度国内生产总值的 0.5%。

NREGS 给村民提供长达 100 天的最低工资工作，这些工作不需要技术，一般为灌溉和公路建设等。NREGS 声明在村民申请后的 15 天内提供工作，否则州政府将支付失业津贴。

NREGS 于 2005 年通过立法，并分三批实施该项目。基于政策的扶贫目的，更贫穷的地区先实施。同时，在第一批实施的地区里面，每个州至少有一个地区参与。三批实施时间如下：

• 第一批：实施时间为 2006 年 2 月，200 个地区参与；
• 第二批：实施时间为 2007 年 4 月，130 个地区参与；
• 第三批：实施时间为 2008 年 4 月，270 个地区参与。

现有对 NREGS 的研究主要采用调查数据，且集中在微观层面。例如，NREGS 通过提高工资增加村民收入 (Imbert 和 Papp，2015；Sukhtankar，2017；Zimmermann，2020)，而这种收入的增加可能主要来自市场的非直接影响 (Muralidharan 等，2017)，当然这种影响也存在地区异质性 (Merfeld，2019)。

为理解 NREGS 项目的宏观影响，本文利用 NREGS 逐步实施这一准自然实验，检验了其对宏观产出 (年度的夜间灯光指数和季度的银行存款) 的影响。

2. 实证模型及主回归结果

本文采用双重差分模型检验 NREGS 实施的影响。其中，以夜间灯光为因变量的样本时间为 2000-2013 年，由于银行存款数据自 2004 年开始，以银行存款数据为因变量的样本时间为 2004-2013 年。为方便解释，将上述变量标准化。实证模型如下：

在上式中， 为地区 在年份/季度 的夜间灯光或者银行存款水平。 是 地区在 年是否实施 NREGS 的虚拟变量。地区虚拟变量为 ， 为年份虚拟变量 州虚拟变量。 为控制变量，主要包括以下三类：

• 政策前的趋势，即夜间灯光 2000-2005 年的增长率，或者银行存款 2004-2005 年的增长率；
• 农村电力项目 (RGGVY) 的实施。RGGVY 的实施是 2005 年，比 NREGS 早一年，影响了样本内的部分地区； 表示地区 是否受到农村电力项目的影响；
• 该地区的贫穷程度指标。政府实施 NREGS 选择每一批地区时会考虑地区的贫穷程度指标，更贫穷的地区先实施。这些指标包括 1991 年人口普查中该地区劣势种姓的比例、1996-1997 年村民收入、以及 1990-1993 年农民平均产出。

由于这些控制变量均不随时间变化，将控制变量与时间虚拟变量交乘，表示为 。在聚类标准误的处理上，本文分别将标准误聚类到地区、地区空间 30km、地区空间 200km，以减少夜间灯光空间相关产生的偏误。

*以夜间灯光数据做Stata示例
use "district light panel.dta", clear

/*
std_lt:经过标准化后的夜间灯光值
nregs:是否实施NREGS
sno:地区
st:州
dlt00_05:2000-2005年的夜间灯光增长率
rggvy:是否实施农村电力保障项目RGGVY
wage:1996-1997年村民收入
outputwage:1990-1993年农民平均产出
state_frac:1991年人口普查中该地区劣势种姓的比例
*/

local pre "i.year#c.wage i.year#c.outputwage i.year#c.state_frac"
*col. 1
reghdfe std_lt nregs, absorb(sno year#st) cluster(sno)
*col. 2
reghdfe std_lt nregs i.year#c.dlt00_05 i.year#i.rggvy, absorb(sno year#st) cluster(sno)
*col. 3
reghdfe std_lt nregs if wage!=., absorb(sno year#st) cluster(sno)
*col. 4
reghdfe std_lt nregs i.year#c.dlt00_05 i.year#i.rggvy if  wage!=., absorb(sno year#st) cluster(sno)
*col. 5
reghdfe std_lt nregs i.year#c.dlt00_05 i.year#i.rggvy `pre', absorb(sno year#st) cluster(sno)

上表为本文的基本结果。第 1 列表明 NREGS 的实施将导致平均夜间灯光指数增加 0.05 个标准差。第 2 列控制了政策前的夜间灯光增长率和该地区是否受 RGGVY 的影响。结果和第 1 列基本一致，表明政策前各地区增长率和 RGGVY 并没有导致 NREGS 的政策影响。

第 3 列和第 4 列重复前两列的检验，但是采用具有地区贫困指标的子样本。第 5 列继续控制地区贫困指标与年份固定效应的交乘。所有的模型均采用地区固定效应和州 年份固定效应。本文也采用年份固定效应替代州 年份固定效应，结果一致。

值得注意的是，NREGS 对夜间灯光的影响程度与中国的经济特区对夜间灯光的影响程度相似 (Alder 等，2016)。

3. 共同趋势假设检验

本文使用以下模型进行共同趋势检验：

*以夜间灯光数据做Stata示例
use "district light panel.dta", clear

local pre "i.year#c.wage i.year#c.outputwage i.year#c.state_frac"

gen wave1=nr06
gen wave2=nr07
gen wave3=nr08
tab year, gen(yr)

*store wave 1 results
forvalues i=1/14{
    gen w`i'=0 if wave1~=.
    replace w`i'=1 if wave1==1 & yr`i'==1
    gen x`i'=0 if wave2~=.
    replace x`i'=1 if wave2==1 & yr`i'==1
}

*omit 2006
replace w6=0 if wave1~=.
replace x6=0 if wave2~=.

*estimation
reghdfe std_lt w1 w2 w3 w4 w5 w6 w7 w8 w9 w10 w11 w12 w13 w14 x1 x2 x3 x4 x5 x6 x7 x8 x9 x10 x11 x12 x13 x14, absorb(sno year#st) cluster(sno)

*store
estadd ysumm
eststo lights_w1

drop w1-w14 x1-x14

*store wave 2 results
forvalues i=1/14{
    gen w`i'=0 if wave2~=.
    replace w`i'=1 if wave2==1 & yr`i'==1
    gen x`i'=0 if wave1~=.
    replace x`i'=1 if wave1==1 & yr`i'==1
}

*omit 2006
replace w6=0 if wave2~=.
replace x6=0 if wave1~=.

*estimation
reghdfe std_lt  w1 w2 w3 w4 w5 w6 w7 w8 w9 w10 w11 w12 w13 w14 x1 x2 x3 x4 x5 x6 x7 x8 x9 x10 x11 x12 x13 x14, absorb(sno year#st) cluster(sno)

*store
estadd ysumm
eststo lights_w2

*label years
forvalue i=1/14{
    local j = 1999+`i'
    label var w`i' "`j'"
}

set scheme s1mono
coefplot (lights_w1, label("Wave 1")) (lights_w2, label("Wave 2")), ///
    keep(w1 w2 w3 w4 w5 w6 w7 w8 w9 w10 w11 w12 w13 w14) vertical   ///
    ytitle(Coefficient on Wave*Year) ylabel(-.5(.1).5) xlabel(,labsize(small)) ///
    yline(0) levels(95) ciopts(lpattern(dash)) omitted baselevels      ///
    groups(w1 w2 w3 w4 w5 w6 = `""{bf:Pre-Rollout}" "(No Districts)""' ///
    w7 w8 w9 = `""{bf:Rollout}" "(Early Districts)""' w10 w11 w12 w13  ///
    w14 = `""{bf:Post-Rollout}" "(All Districts)""')

基准年为 2005 年，即政策实施的前一年。下图绘制了系数和置信区间。该图表明政策实施前第一批实施地区和第二批实施地区，因变量的趋势相对第三批实施地区都没有显著的不同。

用相似的方法，本文也对第三批实施的时间趋势做了检验，下图绘制了系数和置信区间。可见第三批和前两批有不一样的政策后趋势。但是 2006 年政策前的趋势是一致的。政策后，前两批地区的夜间灯光下降了，第三批地区的夜间灯光上升了。

此外，本文对比了三个地区政策实施前因变量的平均值和增长率。可以看出，第三批实施项目的地区在政策前因变量的平均值更高，但是增长率没有显著区别。共同趋势的检验以及这个检验均表明没有违背共同趋势假设。

4. 异质性分析

第一批和第二批实施政策的地区更贫穷，所以先实施项目。那些导致其更加贫穷的因素，例如腐败，也会异质 NREGS 的正面影响。

下表将 NREGS 虚拟变量和第三批实施的虚拟变量 wave3 做交乘。边际效应表明第三批实施的影响显著为正，且为基准回归结果的 2-3 倍。然而 NREGS 的系数没有显著异于 0，说明 NREGS 仅对第三批实施的相对更富裕的地区有正面影响，对第一批和第二批实施的地区没有影响。

5. 稳健性检验

政策实施时间为 2006、2007、2008 年，主回归用的样本为 2000-2013 年和 2004-2013 年，时间跨度太大可能违背共同趋势假设。在稳健性检验中，本文将样本限制在 2004-2010 年，这样设定能够更好地检验政策的影响。所得到的系数比基准回归的系数稍微小一些，这可能是由于 NREGS 实施后的一些宏观方面的积极影响在短期内并不会显现。

进一步排除结果可能受到的农村电力项目 RGGVY 的影响。在稳健性检验中删除所有受到 RGGVY 影响的地区，这大约减少了三分之一的样本，但是结果并没有受到显著影响。

本文政策干预在不同时间发生，根据 Goodman-Bacon(2019) 的最新工作论文，本文检验哪种处理效应导致了 NREGS 的正向影响。将处理效应分解表明政策的正向影响来自以后实施地区为处理组，以先实施地区为实验组的处理效应，而不是以先实施地区为处理组，以后实施地区为对照组的处理效应。该结果与前文政策实施的异质性影响一致。

*App Fig. 1: GB Decomposition, All Waves

xtset sno year
set scheme s1mono
bacondecomp std_lt nregs, ddetail

以下对 Goodman-Bacon(2019) 的说明为笔者补充。

政策干预在不同时间发生，即为交错 DID 模型 (Staggered DID)，在这种情况下，双重差分的拓展形式是双向固定效应模型 (Two-Way Fixed Effects Regression, TWFE)，公式表示为：

如果个体 在 期受到干预，，否则取 0。GB (2019) 认为不能简单将是否受到政策干预的系数解释为政策效应。尤其在异质性的情况下，它是每个群组每一时期效果的加权平均。将交错 DID 用下图表示，在数据中，基本上可以把个体分成三组：从没受到干预的，是纯控制组，用 表示；早期干预组，用 表示， 期开始受到干预；后期干预组，用 表示， 期开始受到干预。

GB (2019) 证明，上述三种情形可以用下图 4 个 22 DID 估计量表示。A、B 图分别以早期干预组和后期干预组作为干预组，以从没受干预的作为控制组得到 22 DID 估计量，C 图用后期干预组被干预之前的数据作为控制组，早期干预组作为干预组，得到 22 DID 估计量，D 图用早期干预组干预后的数据作为控制组，后期干预组作为干预组，得到 22 DID 估计量。GB(2019) 证明 TWFE 估计量实际上是这 4 个 22 DID 估计量的加权平均。

只有假设所有组两两之间均满足平行趋势假设，并且假设每组的因果效应都不存在时变性，TWFE 估计量才可以解释为政策的平均因果效应 (ATT)。现实中政策效应往往具有时变性，即使满足各组两两平行趋势，TWFE 估计量也无法解释为总体平均因果效应。GB (2019) 没有给出合适的估计量，但作者提供了一种分解方法，可以将 TWFE 估计量分解成各部分的加权平均，并提供了相应的 Stata 命令bacondecomp。

6. 将灯光变为收入

为了更好地理解前文的检验，并且将估计结果与现有文献进行对比，本文做了一项粗略的计算，将政策对夜间灯光的影响转为对收入的影响。将 2005 年州层面的人均 GDP 对州的夜间灯光平均值做回归。结果表明，平均夜间灯光增加一个单位，人均 GDP 增加 1785 卢比。

主回归结果的第二列表示 NREGS 可以提高夜间灯光 0.0559 个标准差，转换为人均 GDP，即为人均 GDP 提高 459 卢比，这相当 2005 年人均 GDP 的 2%。考虑到 wave3 地区受到较大的影响，wave3 的人均 GDP 提高 1162 卢比，这相当于 2005 年人均 GDP 的 6%。这一百分比的变化与 Berg 等 (2018) 的估计相似，他们发现在实施效果良好的 NREGS 地区，农业工资增加了约 5%。

7. 总结

本文评估印度一项公共就业政策 NREGS 对经济发展的影响，发现 NREGS 能够增加地区夜间灯光和银行存款。在异质性分析时，发现只有相对富裕的地区受到政策的积极影响。这个结果不仅对印度的扶贫项目，也对世界上其他国家的扶贫项目，具有重要的政策启示，即一些难以观测的因素，例如腐败，会导致地区经济变差，也可能削弱各种扶贫政策带来的积极影响。

尽管结果清晰表明 NREGS 对经济发展存在异质性影响。我们仍然不知道导致第一批和第二批实施没有积极影响的原因是什么。这需要做更多的工作去找到落后地区仍然落后的原因。

最后，考虑到发展中国家可能缺乏详细的地区收入数据，本文使用夜间灯光作为经济发展指标，也可以用于发展中国家检验其他政策的宏观影响。

8. 参考文献

温馨提示： 文中链接在微信中无法生效。请点击底部「阅读原文」。

• Alder S, Shao L, Zilibotti F. Economic reforms and industrial policy in a panel of Chinese cities[J]. Journal of Economic Growth, 2016, 21(4): 305-349. -Link-
• Berg E, Bhattacharyya S, Rajasekhar D, et al. Can public works increase equilibrium wages? Evidence from India’s National Rural Employment Guarantee[J]. World Development, 2018, 103: 239-254. -Link-
• Cook C J, Shah M. Aggregate Effects from Public Works: Evidence from India[J]. Review of Economics and Statistics, 2020: 1-38. -Link-
• Goodman-Bacon A. Difference-in-differences with variation in treatment timing[R]. National Bureau of Economic Research, 2018. -Link-
• Henderson J V, Storeygard A, Weil D N. Measuring economic growth from outer space[J]. American economic review, 2012, 102(2): 994-1028. -Link-
• Imbert C, Papp J. Labor market effects of social programs: Evidence from india's employment guarantee[J]. American Economic Journal: Applied Economics, 2015, 7(2): 233-63. -Link-
• Merfeld J D. Spatially heterogeneous effects of a public works program[J]. Journal of Development Economics, 2019, 136: 151-167. -Link-
• Muralidharan K, Niehaus P, Sukhtankar S. Building state capacity: Evidence from biometric smartcards in India[J]. American Economic Review, 2016, 106(10): 2895-2929. -Link-
• Sukhtankar S. India’s National Rural Employment Guarantee Scheme: What Do We Really Know about the World’s Largest Workfare Program?[C]//India Policy Forum. 2016, 13: 2009-10. -Link-
• Zimmermann L. Why guarantee employment? Evidence from a large Indian public-works program[R]. GLO Discussion Paper, 2020. -Link-

9. 相关推文

Note：产生如下推文列表的命令为：
  lianxh DID 倍分法 差分
安装最新版 lianxh 命令：
  ssc install lianxh, replace

• 专题：Stata命令
• Stata新命令快讯：有向无环图、模糊倍分法等
• 专题：倍分法DID
• Fuzzy DID：模糊倍分法
• DID：仅有几个实验组样本的倍分法 (双重差分)
• 考虑溢出效应的倍分法：spillover-robust DID
• tfdiff：多期DID的估计及图示
• 长差分：Long Difference及Acemoglu AER论文推介
• 倍分法DID：一组参考文献
• Stata：双重差分的固定效应模型-(DID)
• 倍分法(DID)的标准误：不能忽略空间相关性
• Stata：三重差分 DDD 模型简介
• 多期DID之安慰剂检验、平行趋势检验
• DID边际分析：让政策评价结果更加丰满
• Big Bad Banks：多期 DID 经典论文介绍
• Stata 倍分法: 不满足平行趋势假设咋办？
• 多期DID：平行趋势检验图示
• Stata：多期倍分法 (DID) 详解及其图示
• Stata：三重差分模型简介
• 倍分法DID详解 (三)：多时点 DID (渐进DID) 的进一步分析
• 倍分法DID详解 (二)：多时点 DID (渐进DID)
• 倍分法DID详解 (一)：传统 DID
• 专题：内生性-因果推断
• Abadie新作：简明IV,DID,RDD教程和综述