培根分解简介--bacondecomp

clear
local units = 3
local start = 1
local end   = 10

local time = `end' - `start' + 1
local obsv = `units' * `time'
set obs `obsv'

egen id    = seq(), b(`time')  
egen t     = seq(), f(`start') t(`end')  

sort  id t
xtset id t

lab var id "Panel variable"
lab var t  "Time  variable"

gen D = 0
replace D = 1 if id==2 & t>=5
replace D = 1 if id==3 & t>=8
lab var D "Treated"

gen Y = 0
replace Y = D * 2 if id==2 & t>=5
replace Y = D * 4 if id==3 & t>=8

lab var Y "Outcome variable"

如果我们绘制这个：

twoway ///
 (connected Y t if id==1) ///
 (connected Y t if id==2) ///
 (connected Y t if id==3) ///
  , ///
  xline(4.5 7.5) ///
  xlabel(1(1)10) ///
  legend(order(1 "id=1" 2 "id=2" 3 "id=3"))

我们得到：

在图中，我们可以看到处理发生在两个不同的点。对 id=2 的处理发生在tt=5，而对 id=3 的处理发生在tt=8。当第二次处理发生时，id=2 已经得到处理，并且基本上是恒定的。因此，对于 id=3，id=2 也是预处理组的一部分，特别是如果我们只考虑时间范围5≤t≤10。仅从图中看，也不清楚在这种情况下的 ATT 应该是多少，因为我们无法再像 TWFE 部分讨论的更简单的示例那样平均处理大小。

为了恢复这一点，我们可以运行一个简单的模型：

xtreg Y D i.t, fe 
reghdfe Y D, absorb(id t)   // alternative specification

这给了我们一个 ATT所对应的β值为 2.91。总而言之，这是考虑时间和面板固定效应后的平均处理效应。

回到图中，这种处理和未处理、早期和晚期处理的相对分组是新的DiD论文的一部分，只是因为这些组合中的每一个在总体平均值上都发挥着自己的作用，这正是培根分解告诉我们的。它从三个不同的 2x2 组估计的DID系数进行了分解：

处理过（T)对从未处理过（U)
早期处理（Te)对晚期控制（Cl**)**
晚期处理（Tl)对早期控制（Ce)

换言之，面板 ID 根据第一次处理发生的时间以及它与其他面板 ID 的处理相关的位置，被划分为不同的时间队列。面板 ID 和差异处理时间越多，上述组的组合就越多。

在我们的简单示例中，我们有两个经过处理的面板 ID：id=2（早期处理）Te）和 id=3（晚期处理Tl).处理与从未处理可以进一步分为早期处理与从未处理（Te与U）和晚期处理与从未处理（Tl与U).如果有三组，则总共估计了四组值。

Goodman-Bacon在论文中也使用了类似的例子。

每组值本质上都是一个基本的 2x2 TWFE 模型.

我们稍后会回到这些。但首先，让我们看看bacondecomp命令为我们提供了什么：

bacondecomp Y D, ddetail

在没有控制变量的情况下，我们得到如下结果

该图显示了我们示例中三个组的四个点。处理与从未处理（T与U）显示为三角形。十字架代表晚期与早期处理（Tl与Te）组合。空心圆圈代表时间组或早期与晚期处理组（Te与Tl).

图示信息显示在表格输出中：

Computing decomposition across 3 timing groups
including a never-treated group
------------------------------------------------------------------------------
           Y | Coefficient  Std. err.      z    P>|z|     [95% conf. interval]
-------------+----------------------------------------------------------------
           D |   2.909091   .3179908     9.15   0.000      2.28584    3.532341
------------------------------------------------------------------------------

Bacon Decomposition

+---------------------------------------------------+
|                      |         Beta   TotalWeight |
|----------------------+----------------------------|
|         Early_v_Late |            2   .1818181841 |
|         Late_v_Early |            4   .1363636317 |
|       Never_v_timing |  2.933333323   .6818181841 |
+---------------------------------------------------+

在这里，我们得到我们的权重和对于每组2x2所对应的β值。该表告诉我们（T与U），即晚期和早期处理与从未处理的总和，权重最大，其次是早期处理与晚期处理，最后是晚期与早期处理。

让我们看一下存储的信息：

ereturn list

感兴趣的关键矩阵是：e(summdd)

mat list e(sumdd)

这为我们提供了以下内容：

e(sumdd)[3,2]
                     Beta  TotalWeight
Early_v_Late            2    .18181818
Late_v_Early            4    .13636363
Never_v_ti~g    2.9333333    .68181818

从这个矩阵中，我们可以计算β:

display e(sumdd)[1,1]*e(sumdd)[1,2] + e(sumdd)[2,1]*e(sumdd)[2,2] + e(sumdd)[3,1]*e(sumdd)[3,2]

这给了我们原始的β= 2.909，作为早期、晚期和从未处理过的组的不同 2x2 组合的加权和。这种分解本质上是培根分解的核心点。

http://mp.weixin.qq.com/s?__biz=MjM5NTM4NjU2OA==&mid=2650757987&idx=2&sn=538d3fa3fa82aba2a5ccc2f1205f4630

培根分解简介--bacondecomp

DID主题文章推荐